Winding line on a torus 

Description: 

This worksheet illustrates how to use atlas package to solve problems in elementary differential geometry. As an example we calculate curvatures and moving frame of a winding line on a torus. On the one hand the line is embedded into the Euclidian space. On the other hand the line is embedded into the torus. We assume that the torus is embedded into the Euclidian space and the metric tensor field of the torus is just the induced metric of the embedding. 

   

In the first case we calculate the moving frame: principal normal, binormal and tangent vector fields for the embedded curve. We also calculate first and second curvatures of the embedded curve which are known as curvature and torsion of the curve.
In the second case we calculate the moving frame: principal normal and tangent vector fields for the embedded curve. Besides that we calculate first curvature of the embedded curve.
As intermediate results we obtain first fundamental forms induced by the corresponding embedding on the curves and torus (metric tensor field for torus and squared differential of the curve's arc for curves). Besides that we obtain second fundamental form and mean curvature vector field of the embedded torus.    

Solution: 

Load atlas package: 

>	restart: with(atlas):

 

Just for right simplification: 

>	`atlas/simp`:=proc(a) factor(simplify(a,trig)) end:

 

Description of the total space  

First of all we have to describe the space we are working in. The space is 3-dimensional Euclidean (flat) space. To define the space we declare domain, forms, vectors, coframe, frame, flat metric and calculate connection (it is equal to zero of course). 

Define Euclidean space as a manifold:
Domain(R^3); 

(2.1.1)

 

Declare 1-forms for the space coframe:
Forms(e[k]=1); 

(2.1.2)

 

Declare vectors for the space frame:
Vectors(E[j]); 

(2.1.3)

 

Declare coframe on the space:
Coframe(e[1]=d(x),e[2]=d(y),e[3]=d(z)); 

(2.1.4)

 

Declare frame on the space:
Frame(E[k]); 

(2.1.5)

 

Declare flat metric on the space:
Metric(g[R]=d(x)&.d(x)+d(y)&.d(y)+d(z)&.d(z)); 

(2.1.6)

 

Calculate connection of the metric:
Connection(omega); 

(2.1.7)

 

Description of the curve C (winding line on a torus) 

Define the curve as a manifold:
Domain(C); 

(2.2.1)

 

Declare constants a, b and m, n:
Constants(a,b,m,n); 

(2.2.2)

 

Declare 1-form for curve's coframe
Forms(u[i]=1); 

(2.2.3)

 

Declare vectors for curve's frame:
Vectors(U[k]); 

(2.2.4)

 

Declare coframe on the curve:
Coframe(u[1]=d(tau)); 

(2.2.5)

 

Declare frame of the curve:
Frame(U[l]); 

(2.2.6)

 

Mapping : and its invariants (metric, moving frame, curvature, torsion) 

Declare mapping of the curve into :
Mapping(pi,C,R^3,x=(a+b*cos(n*tau))*cos(m*tau),
                y=(a+b*cos(n*tau))*sin(m*tau),
                z=b*sin(n*tau)); 

 

	(2.3.1)

 

One can also calculate metric induced on the curve by the mapping: 

>	Metric(g[C] = g[R] &/ pi);

 

(2.3.2)

 

It is obvious that the metric gives squared differential of the curve's arc:  

Calculate invariants of the mapping:
Inv[pi]:=Invariants(pi): 

Extract tangent normalized vector field: 

>	T1:=Inv[pi][basis][0];

 

(2.3.3)

 

Extract principal normal normalized vector field: 

>	N1:=Inv[pi][basis][1];

 

(2.3.4)

 

Extract binormal normalized vector field: 

>	B1:=Inv[pi][basis][2];

 

(2.3.5)

 

Extract curvature of the curve: 

>	k1:=Inv[pi][curvatures][1];

 

(2.3.6)

 

Extract torsion of the curve: 

>	chi1:=Inv[pi][curvatures][2];

 

(2.3.7)

 

Let us check the "orthonormality" of the moving frame vectors. To do this we use metric tensor field :   

>	'g[R](T1,T1)'=simplify(g[R](T1,T1)); 'g[R](B1,B1)'=simplify(g[R](B1,B1)); 'g[R](N1,N1)'=simplify(g[R](N1,N1));

 

 

 

	(2.3.8)

 

>	'g[R](T1,N1)'=simplify(g[R](T1,N1)); 'g[R](T1,B1)'=simplify(g[R](T1,B1)); 'g[R](B1,N1)'=simplify(g[R](B1,N1));

 

 

 

	(2.3.9)

 

Description of the torus  

Define the torus  as a manifold:
Domain(T^2); 

(2.4.1)

 

Declare 1-form for the torus coframe
Forms(phi[i]=1); 

(2.4.2)

 

Declare vectors for the torus frame:
Vectors(Phi[j]); 

(2.4.3)

 

Declare coframe on the torus:
Coframe(phi[1]=d(alpha),phi[2]=d(beta)); 

(2.4.4)

 

Declare frame of the torus:
Frame(Phi[l]); 

(2.4.5)

 

Embedding  : and induced metric calculation  

Declare mapping of the torus into :
Mapping(f,T^2,R^3,x=(a+b*cos(beta))*cos(alpha),
                 y=(a+b*cos(beta))*sin(alpha),
                 z=b*sin(beta)); 

 

	(2.5.1)

 

Calculate metric (induced by the embedding) on the torus using `&/` operator:
Metric(g[T] = g[R] &/ f); 

(2.5.2)

 

Calculate connection on the torus
Connection(Gamma); 

(2.5.3)

 

Let us see the result:
eval(Gamma); 

(2.5.4)

 

We can calculate the corresponding invariants of the mapping. The invarians are: second fundamental form and field of mean curvature vectors. We do not need these quantities anyway, but it's hard to keep from the calculation:  

>	Inv[f]:=Invariants(f);

 

(2.5.5)

 

Embedding : and its invariants (metric, moving frame, curvature) 

Declare mapping of the curve into :
Mapping(psi,C,T^2,
            alpha=m*tau,
            beta=n*tau); 

 

	(2.6.1)

 

Calculate metric (induced by the embedding) on the curve using `&/` operator:
g[T] &/ psi; 

(2.6.2)

 

Calculate invariants of the mapping:
Inv[psi]:=Invariants(psi); 

(2.6.3)

 

Extract tangent normalized vector field: 

>	T2:=Inv[psi][basis][0];

 

(2.6.4)

 

Extract principal normal normalized vector field: 

>	N2:=Inv[psi][basis][1];

 

(2.6.5)

 

Extract curvature of the curve: 

>	k2:=Inv[psi][curvatures][1];

 

(2.6.6)

 

Let us check the "orthonormality" of the moving frame vectors. To do this we use metric tensor field , but in this case the metric is not flat and its components (in any coframe) are verify from one torus point to another:    

>	g[T]=ToBasis(g[T]);

 

(2.6.7)

 

Thus we have to make calculations on the curve C: 

>	sub:={alpha=m*tau,beta=n*tau};

 

(2.6.8)

 

>	'g[T](T2,T2)'=simplify(subs(sub,g[T](T2,T2))); 'g[T](N2,N2)'=simplify(subs(sub,g[T](N2,N2)));

 

 

	(2.6.9)

 

>	'g[T](T2,N2)'=simplify(subs(sub,g[T](T2,N2)));

 

(2.6.10)

 

>